@echo off
REM ---------------------------------------------------------------------------
REM  Mein Audi (DataMetric360) - Installation per Doppelklick.
REM
REM  Existiert, weil ein Doppelklick auf eine .ps1 sie NICHT ausfuehrt, sondern
REM  im Editor oeffnet - und die Ausfuehrungsrichtlinie sie zusaetzlich blockt.
REM  Dieser Wrapper startet install.ps1 mit -ExecutionPolicy Bypass, gilt aber
REM  nur fuer diesen einen Aufruf: die Einstellung des Systems bleibt, wie sie
REM  ist. Deshalb hier -File und kein Herunterschrauben per Set-ExecutionPolicy.
REM ---------------------------------------------------------------------------
setlocal
cd /d "%~dp0"

powershell -NoProfile -ExecutionPolicy Bypass -File "%~dp0install.ps1" %*
set FEHLER=%ERRORLEVEL%

echo.
if not "%FEHLER%"=="0" (
  echo   Die Installation wurde mit einem Fehler abgebrochen ^(Code %FEHLER%^).
  echo   Die Meldung darueber sagt, woran es lag.
  echo.
)
REM Fenster offen halten - sonst ist die Ausgabe beim Doppelklick sofort weg.
pause
endlocal
exit /b %FEHLER%